# Guihong Fan, Gail S. K. Wolkowicz. Chaotic dynamics in a simple predator-prey model with discrete delay. 
# Discrete and Continuous Dynamical Systems - B, 2021, 26(1): 191-216. doi: 10.3934/dcdsb.2020263
# https://www.researchgate.net/publication/343390059

# eqs (5)
x'=r*x*(1-x/K) - m*y*x
y'=-s*y + Y_*exp(-s*tau)*m*delay(y,tau)*delay(x,tau)

p tau=1,s=0.02,m=1,r=1,K=1,Y_=0.6

aux xtau=delay(x,tau)
aux ytau=delay(y,tau)

# critical values of x 
dxcrit/dt=0
# critical values of y
dycrit/dt=0

# global: detect critical values of x ant set xcrit to x
# global -1 detect when x' crosses 0 from above (x is a max)
global -1 r*x*(1-x/K) - m*y*x {xcrit = x}
# global 1 detect when x' crosses 0 from below (x is a min)
global  1 r*x*(1-x/K) - m*y*x {xcrit = x}

# global: detect critical values of y ant set ycrit to y
# global -1 detect when y' crosses 0 from above (y is a max)
global -1 -s*y + Y_*exp(-s*tau)*m*delay(y,tau)*delay(x,tau) {ycrit = y}
# global 1 detect when y' crosses 0 from below (y is a min)
global  1 -s*y + Y_*exp(-s*tau)*m*delay(y,tau)*delay(x,tau) {ycrit = y}

# Make tau a plottable variable
aux taubif=tau

# initial conditions
init x=0.1,y=0.1
init xcrit=0.0

# XPP settings
@ bound=1000000,total=20000
@ delay=130
@ maxstor=100000
@ transient=16000
@ dt=1
@ xp=taubif,yp=ycrit,xlo=1,ylo=0,xhi=120,yhi=2.5

# Range settings
@ range=1,rangeover=tau
@ rangereset=no
@ rangelow=1,rangehigh=120,rangestep=200
@ lt=0

done