# Mackey-Glass Equation 
# Mackey & Glass (1977) Science, equation 4b
#  
#  dx(t)   beta0 theta^n x(t-tau)
#  ----- = ---------------------- - gamma x(t)
#   dt      theta^n + x(t-tau)^n
#

# parameters
p beta0=0.2
p gamma=0.1
p n=10
p theta=1

# nonlinear functions
f(x)=beta0*theta^n*x/(theta^n+x^n)

# equation
dx/dt=f(delay(x,tau)) - gamma*x

# auxiliary xtau for plotting
aux xtau=delay(x,tau)

# critical values of x 
dxcrit/dt=0

# global: detect critical values of x ant set xcrit to x
# global -1 detect when x' crosses 0 from above (x is a max)
global -1 f(delay(x,tau)) - gamma*x {xcrit = x}
# global 1 detect when x' crosses 0 from below (x is a min)
global  1 f(delay(x,tau)) - gamma*x {xcrit = x}

p tau=1.0
# Make tau a plottable variable
aux taubif=tau

# initial conditions
init x=0.1
init xcrit=0.0

# XPP settings
@ bound=1000000,total=2000
@ delay=30
@ maxstor=100000
@ transient=700
@ dt=1
@ xp=taubif,yp=xcrit,xlo=1,ylo=0,xhi=21,yhi=2.0

# Range settings
@ range=1,rangeover=tau
@ rangereset=no
@ rangelow=1,rangehigh=20,rangestep=200
@ lt=0

done